[chuck-users] the return of the abused models
Kassen
signal.automatique at gmail.com
Tue Apr 22 11:16:56 EDT 2008
Hi, list.
Some time ago we talked about abusing the STK models for getting strange
sounds, I found a nice new one using StifKarp. I was controlling the
"stretch" parameter with my new tilt-sensing joypad and discovered that
shaking the joypad led to nice noises. Here's a demo without the joypad for
your enjoyment.
Cheers,
Kas.
===========================
//"spooky sound" by Kassen.
//Permission granted to modify and copy.
//No warranties, no refunds, please mind your speakers and neighbours.
//Remixing strongly encouraged.
StifKarp s => dac;
//low frequency for nice spooky sound
50 => s.freq;
//the following lines are to have a note-on without actually
//hearing the default pluck. StifKarp won't make a sound without one
0 => s.gain;
1=> s.noteOn;
2::second => now;
//turn it up again
.8=> s.gain;
.9 => s.sustain;
//exciting signal
TriOsc lfo => ADSR env => blackhole;
//works better if it's a sub-harmonic of the pitch, I think
25 => lfo.freq;
second => env.attackTime;
second => env.decayTime;
.5=> env.gain;
//connects the lfo's signal to the StifKarp "stretch"
//see below
spork ~ envctrl();
int counter;
while(counter < 20)
{
1=> env.keyOn;
3::second => now;
1=> env.keyOff;
1::second => now;
counter++;
}
//allow it to decay for a bit
2::second => now;
//bye
fun void envctrl()
{
//the offset and the envelope's gain combine to
//make sure the value stays in stretch's range
while(10::ms => now) env.last() + .5 => s.stretch;
}
-------------- next part --------------
An HTML attachment was scrubbed...
URL: http://lists.cs.princeton.edu/pipermail/chuck-users/attachments/20080422/54416b27/attachment.htm
More information about the chuck-users
mailing list